Сообщений в теме: 9

[lepis]

Здравствуйте!

У меня написано около сотни тестов. Тестируемое приложение переезжает с одного сервера на другой, т.е. у него становится другой адрес. Как мне изменить адрес в тесте? В самом скрипте (в Expert View) я не нашел строки с адресом первой страницы теста. В мануале ничего не нашел по этому поводу.

Заранее спасибо.

[M.J.K]

По моему опыту - неплохое решение данной проблемы:
Создаем внешнию библиотеку, в которой пишем что-то типа:

Environment("Server") = "http://server"

Dim qtApp 'As QuickTest.Application ' Declare the application object variable 
Dim qtSettings 'As QuickTest.Application ' Declare the application object variable 

Set qtApp = CreateObject("QuickTest.Application") ' Create the application object 

Set qtSettings = qtApp.Test.Settings
' Configure the Web application to use with this test 
If qtSettings.Launchers("Web").Active then
	qtSettings.Launchers("Web").Address = Environment("Server") 
	qtSettings.Launchers("Web").CloseOnExit = True
End if

- надеюсь, особых пояснений не нужно?
И затем подцепляете эту библиотеку ко всем тестам.

В результате при "переезде" приложения на другой сервер - правите путь лишь в одном файле библиотеки.

[Rifle]

Библиотеку надо было использовать с самого начала, ну а если уже написано сотни скриптов, то можно воспользоваться банальной пакетной автозаменой. Программка которая вам поможет 'RQ Search & Replace'.

ИМХО PS: на будущие я бы все-таки переписал скрипты, и делал инклуд конфиг файла с описаниями переменных в скрипте

[M.J.K]

Библиотеку надо было использовать с самого начала, ну а если уже написано сотни скриптов, то можно воспользоваться банальной пакетной автозаменой. Программка которая вам поможет 'RQ Search & Replace'.

ИМХО PS: на будущие я бы все-таки переписал скрипты, и делал инклуд конфиг файла с описаниями переменных в скрипте

В принципе, Rifle прав, но ... не доверяю я неизвестным exe-файлам.
Описанную процедуру можно делать используя всё тот-же vb script:

Dim fso, f, sf, fl,TestFolder,NewURL
Dim qtApp 

' Set the path to the Test folder here
TestFolder="C:\Program Files\Mercury Interactive\QuickTest Professional\Tests\"

' Set the new URL for the Record and Run settings here.
NewURL="http://www.google.com"

' Create a file system object to dynamically loop through all the tests
Set fso = CreateObject("Scripting.FileSystemObject") 
Set f = fso.GetFolder(TestFolder) 
Set sf = f.SubFolders

' Create a QuickTest Professional instance
Set qtApp = CreateObject("QuickTest.Application")

' Loop through all the tests
For each fl in sf
   ' Open the specified test
   qtApp.Open TestFolder & fl.name, False, False
   ' Update the URL
   qtApp.Test.Settings.Launchers("Web").Address = NewURL 'Change URL
   ' Save the modified test
   qtApp.Test.Save 
Next

' Close the QuickTest Professional instance
qtApp.Quit
' Release the objects
Set qtApp = Nothing 
Set sf = Nothing
Set f = Nothing
Set fso = Nothing

msgbox "Done"

если нужны комментарии - обращайтесь!

[M.J.K]

Кстати, как еще вариант - сначала написать библиотеку из моего первого поста, а потом прикрепить её ко всем тестам немного измененным вариантом из последнего.
И будет Вам Щастье :)

[lepis]

Описанную процедуру можно делать используя всё тот-же vb script:

Dim fso, f, sf, fl,TestFolder,NewURL
Dim qtApp 

' Set the path to the Test folder here
TestFolder="C:\Program Files\Mercury Interactive\QuickTest Professional\Tests\"

' Set the new URL for the Record and Run settings here.
NewURL="http://www.google.com"

' Create a file system object to dynamically loop through all the tests
Set fso = CreateObject("Scripting.FileSystemObject") 
Set f = fso.GetFolder(TestFolder) 
Set sf = f.SubFolders

' Create a QuickTest Professional instance
Set qtApp = CreateObject("QuickTest.Application")

' Loop through all the tests
For each fl in sf
   ' Open the specified test
   qtApp.Open TestFolder & fl.name, False, False
   ' Update the URL
   qtApp.Test.Settings.Launchers("Web").Address = NewURL 'Change URL
   ' Save the modified test
   qtApp.Test.Save 
Next

' Close the QuickTest Professional instance
qtApp.Quit
' Release the objects
Set qtApp = Nothing 
Set sf = Nothing
Set f = Nothing
Set fso = Nothing

msgbox "Done"

то есть этот скрипт изменит адрес во всех тестах, которые лежат в папке TestFolder?

[lepis]

да, работает :) спасибо большое

[M.J.K]

да, работает :) спасибо большое

Пожалуйста!
Всё-таки посоветовал бы использовать внешние библиотеки с настройками, чем после каждого "переезда" запускать этот скрипт.
Удачи!

[ShortLegged]

Возможно ли указывать непосредственно в экшене адрес приложения и открывать браузер именно с этим адресом?

Спасибо.

[M.J.K]

Возможно ли указывать непосредственно в экшене адрес приложения и открывать браузер именно с этим адресом?

Спасибо.

Легко:

SystemUtil.Run "explore.exe", "http://ya.ru"